;
; PURPOSE: produce an image for Carrington maps that can be overlad by CONTOURs & lines
; MODIFIED: 24March2005 Xuepu Zhao for adding keyword sy
; NOTE: the MDI SC is in equal step of LATITUDE 27APR2006 Xuepu
;       the WSO SC is in equal step of SIN(lat)
;
PRO pimg06,bimg,tt,px,py,swx,swy,SY=sy,CSZ=csz

    if N_params() LT 1 then begin
       print,'PRO pimg06,bimg,tt,px,py,sy=,csz='
       print,"sy = 'lat','sla','nml', csz=1.0"
       return
    endif
    if not keyword_set(csz) then csz=1.0
    if not keyword_set(sy) then sy='nml'
    interp=1
    sz=size(bimg)
    six = float(sz(1))              ;Image sizes
    siy = float(sz(2))
    ;set window used by contour or plot
    plot,[[0,0],[1,1]],/nodata,xstyle=5,ystyle=5,title=tt,$
         xrange=[0,six-1],yrange=[0,siy-1],charsize=csz
    px = !x.window * !d.x_vsize     ;Get size of window in device units
    py = !y.window * !d.y_vsize
    swx = px(1)-px(0)               ;Size in x in device units
    swy = py(1)-py(0)               ;Size in Y
    if (!d.flags and 1) ne 0 then begin           ;Scalable pixels
       tv,bimg,px(0),py(0),xsize=swx,ysize=swy,/device
    endif else begin                              ;Not scalable pixels
       bimgn = poly_2d((bimg),[[0,0],[six/swx,0]], $
             [[0,siy/swy],[0,0]],interp,swx,swy)
       tv,bimgn,px(0),py(0)
    endelse
    return

END