;
; PURPOSE: produce an image for Carrington maps that can be overlad by CONTOURs & lines
; MODIFIED: 24March2005 Xuepu Zhao for adding keyword sy
; NOTE: the MDI SC is in equal step of LATITUDE 27APR2006 Xuepu
;       the WSO SC is in equal step of SIN(lat)
; MODIFIED: 14SEP2006   Xuepu for adding keyword std
;
PRO pscimg06,bimg,tt,px,py,SY=sy,CSZ=csz,STD=std

    if N_params() LT 1 then begin
       print,'PRO pscimg06,bimg,tt,px,py,sy=,csz=,/std'
       print,"sy = 'lat','sla'; csz=1.0"
       print,'/std -- Standard SC with 180 centered'
       return
    endif
    if not keyword_set(csz) then csz=1.0
    interp=1
    CASE 1 OF                       ;set window used by contour or plot
      sy eq 'lat': plot,[[0,0],[1,1]],/nodata,xstyle=5,ystyle=5,title=tt,$
                        xrange=[0,360],yrange=[-90,90],charsize=csz
      sy eq 'sla': plot,[[0,0],[1,1]],/nodata,xstyle=5,ystyle=5,title=tt,$
                        xrange=[0,360],yrange=[-1,1],charsize=csz
      else:        plot,[[0,0],[1,1]],/nodata,xstyle=5,ystyle=5,title=tt,$
                        xrange=[0,1],yrange=[0,1],charsize=csz
    ENDCASE                         
    px = !x.window * !d.x_vsize     ;Get size of window in device units
    py = !y.window * !d.y_vsize
    swx = px(1)-px(0)               ;Size in x in device units
    swy = py(1)-py(0)               ;Size in Y
    sz=size(bimg)
    six = float(sz(1))              ;Image sizes
    siy = float(sz(2))
    if (!d.flags and 1) ne 0 then begin           ;Scalable pixels
       tv,bimg,px(0),py(0),xsize=swx,ysize=swy,/device
    endif else begin                              ;Not scalable pixels
       bimgn = poly_2d((bimg),[[0,0],[six/swx,0]], $
             [[0,siy/swy],[0,0]],interp,swx,swy)
       tv,bimgn,px(0),py(0)
    endelse
    if keyword_set(std) then begin
       xnon = REPLICATE(' ', 2)
       xtic=['0',xnon,'90',xnon,'180',xnon,'270',xnon,'360']
       CASE 1 OF                       ;set window used by contour or plot
         sy eq 'lat': sc_annot,1,/lat
         sy eq 'sla': sc_annot,1
         else:        sc_annot,1,/norm
       ENDCASE
    endif

END