;
; PURPOSE: read a WSO SC data file obtained from WSO Web
; NOTE:    Latitudal grid is not homogeneous (SIN(lat))
; WRITTEN: 02May2000  Xuepu Zhao
;
FUNCTION readwsosc,scfile,CALI=cali,BR=br,DISP=disp

   if N_params() LT 1 then begin
      print,'SYNTAX - FUNCTION readwsosc,scfile,/cali,/br,/disp'
      print,'OUTPUT - wsc with 73 X 30'
      return,-1
   endif
print,'This is /home/xuepu/ZIDLLIB/CSSS/readwsosc.pro'
   str=' '
   wsc=fltarr(73,30)
   sct=strarr(73)
   bl=fltarr(30)
   get_lun,unit
   openr,unit,scfile
   for k=0,2 do readf,unit,str
   fmt='(a18,6f9.3,3(/,8f9.3))'
   for xi=0,72 do begin
       readf,unit,format=fmt,str,bl
       wsc(xi,*)=bl
       sct(xi)=str
   endfor
   free_lun,unit
   
   wsc0=wsc
   for i=0,72 do for j=0,29 do wsc(i,j)=wsc0(72-i,29-j) ; match zgrid.pro

   zgrid,73,30,phd,thd,lad,cth,sth,csc,scs
 ; phd=findgen(73)*5

   if keyword_set(cali) then begin
      for j=0,29 do wsc(*,j)=wsc(*,j)*(4.5-2.5*cth(j)*cth(j))
   endif

   if keyword_set(br) then begin
      for j=0,29 do wsc(*,j)=wsc(*,j)/sth(j)
   endif

   if keyword_set(disp) then begin
      srt=strmid(sct(0),2,4)
      ttw='WSO CR'+srt+'  73 X 30'
      wsccon=CONGRID(wsc,432,180,/interp)
      wscsmt=SMOOTH(wsccon,6,/edge_truncate)
;print,max(wscsmt),min(wscsmt)
      bwscsmt=BYTSCL(wscsmt,max=6400,min=-6400)
      pimg0,bwscsmt,ttw,px,py
      sc_annot,1,/norm
      CONTOUR,wscsmt,POS=[px(0),py(0),px(1),py(1)],$
              level=[0],c_colors=[250],c_thick=[2],$
              xstyle=5,ystyle=5,/dev,/noerase
   endif

   return,wsc

end