;
; WRITTEN:  Xuepu Zhao  12June2009
;
pro crncrl_date,date,crn,crl,crl0,PLT=plt

    if n_params( ) lt 1 then begin
       print,'crncrl_date,date,crn,crl, crl0,/plt'
       return
    endif
; Time
    year_sec_date,date,year,month,day,hh,mm,ss
    ny=year-1995+1
    yeart=INDGEN(ny)+1995
    fday=-1
    for yn=0,ny-1 do begin
        if yn lt (ny-1) then begin
           yeari=yeart(yn)
           res=yeari MOD 4
           if res gt 0 then fday=fday+365 else fday=fday+366
        endif else begin
           year=yeart(yn)
           dmy2doy,year,month,day,doy
           fday=fday+doy
        endelse
    endfor
    fday=fday+hh/24.+mm/(24.*60)+ss/86400.
; CRl
    degs=349.03 - (360.* fday / 27.2753)
    if degs lt 0 then dcrn=-FIX(degs/360.)+1 else dcrn=-FIX(degs/360)
    crn=dcrn+1891
    crl0=degs+dcrn*360.
    a=1.91787 & b=-0.13067 & c=-8.25278E-2 & d=-0.17505
    e=365.27116 & f=0.26318  & g=-26379.45   & h=5.20448E-3
    i=-5.56336E-3  & j=-1.22842E-2
    pi=!PI
    Fit = f + fday/g + a*SIN(2*pi*fday/e) + b*SIN(4*pi*fday/e) + h*SIN(6*pi*fday/e) + c*COS(2*pi*fday/e) + d*COS(4*pi*fday/e) + i*COS(6*pi*fday/e)
    crl=crl0+Fit
    if keyword_set(plt) then print,'crn,crl0,crl:',crn,crl0,crl

end